// displays an information, if the CapsLock is activated

OPT	OPTIMIZE

MODULE	'devices/input','exec/io','input','devices/inputevent'
MODULE	'commodities','libraries/commodities','dos/dos'
MODULE	'intuition/intuition','utility/tagitem','intuition/screens','intuition/intuitionbase'

DEF	InputBase
DEF	broker=NIL,broker_mp=NIL:PTR TO MP,cxsigflag,CXBase

DEF	caps_window=NIL:PTR TO Window
DEF	display_caps=FALSE		// if TRUE, then we display the icon

PROC main()
	DEF	request=NIL:PTR TO IOStd,port=NIL,msg
	IF CXBase:=OpenLibrary('commodities.library',37)
		IF broker_mp:=CreateMsgPort()
			IF broker:=CxBroker([
					NB_VERSION,
					'capslock',
					'capslock v1.0 by MarK',
					'displays icon if CapsLock key pressed.',
					0,0,0,
					broker_mp,
					0]:NewBroker,NIL)

				cxsigflag:=1<<broker_mp.SigBit


				IF port:=CreateMsgPort()
					IF request:=CreateIORequest(port,SIZEOF_IOStd)
						IF OpenDevice('input.device',0,request,0)=0
							InputBase:=request.Device

							IF PeekQualifier()&IEQUALIFIER_CAPSLOCK
								PrintF('capslock pressed\n')
							ENDIF

							ActivateCxObj(broker,TRUE)
							display_caps:=TRUE

							ProcessMsg()

							close_caps_window()

							CloseDevice(request)
						ELSE PrintF('\s: could not open input device\n','capslock')
						DeleteIORequest(request)
					ELSE PrintF('\s: could not create iorequest\n','capslock')
					DeleteMsgPort(port)
				ELSE PrintF('\s: could not open port\n','capslock')
				DeleteCxObj(broker)
			ELSE PrintF('\s: could not create broker\n','capslock')

			// cleare message port
			WHILE msg:=GetMsg(broker_mp) DO ReplyMsg(msg)
			DeleteMsgPort(broker_mp)
		ELSE PrintF('\s: could not open port\n','capslock')
		CloseLibrary(CXBase)
	ELSE PrintF('\s: no commodities.library v37+\n','capslock')
ENDPROC

PROC ProcessMsg()
	DEF	msg,sigrcvd,msgid,msgtype,done=FALSE
	REPEAT
//		sigrcvd:=Wait(cxsigflag|SIGBREAKF_CTRL_C)

		Delay(10)	// stupid wait routine

		WHILE msg:=GetMsg(broker_mp)
			msgid:=CxMsgID(msg)
			msgtype:=CxMsgType(msg)
			ReplyMsg(msg)
			SELECT msgtype
			CASE CXM_IEVENT
			CASE CXM_COMMAND
				SELECT msgid
				CASE CXCMD_DISABLE;	ActivateCxObj(broker,FALSE);	display_caps:=FALSE
				CASE CXCMD_ENABLE;	ActivateCxObj(broker,TRUE);	display_caps:=TRUE
				CASE CXCMD_KILL;		PrintF('bye bye.\n');		done:=TRUE
				ENDSELECT
			DEFAULT;						PrintF('Unknown msgtype\n')
			ENDSELECT
		ENDWHILE
		IF PeekQualifier()&IEQUALIFIER_CAPSLOCK
			IF display_caps
				open_caps_window()
			ELSE
				close_caps_window()
			ENDIF
		ELSE
			close_caps_window()
		ENDIF
		IF CtrlC()
			PrintF('bye bye.\n')
			done:=TRUE
		ENDIF
	UNTIL done
ENDPROC

PROC open_caps_window()
	DEF	scr:PTR TO Screen
	scr:=get_front_screen()
	IFN caps_window	// window isn't opened yet
		caps_window:=OpenWindowTags(NIL,
			WA_Width,scr.Width/16,
			WA_Height,scr.Height/16,
			WA_Left,scr.Width-2*scr.Width/16,
			WA_Top,scr.Height/16,
			WA_Flags,WFLG_BORDERLESS,
			WA_ScreenTitle,'Press CapsLock to close me\n',
			WA_CustomScreen,scr,
			TAG_END)
		SetRast(caps_window.RPort,1)
		SetAPen(caps_window.RPort,2)
		RectFill(caps_window.RPort,5,5,caps_window.Width-5,caps_window.Height-5)
	ELSE	// window opened already
		IF caps_window.WScreen<>scr
			close_caps_window()	// close the window on back screen
			open_caps_window()	// open the window on the front screen
		ENDIF
	ENDIF
ENDPROC

PROC close_caps_window()
	IF caps_window THEN CloseWindow(caps_window)
	caps_window:=NIL
ENDPROC

PROC get_front_screen()(PTR TO Screen)
	DEF	scr:PTR TO Screen
	scr:=IntuitionBase::IntuitionBase.ActiveWindow.WScreen
ENDPROC scr